1/*        $NetBSD: sigsetjmp.S,v 1.20 2025/05/03 19:55:32 riastradh Exp $       */
2
3/*-
4 * Copyright (c) 1990 The Regents of the University of California.
5 * All rights reserved.
6 *
7 * This code is derived from software contributed to Berkeley by
8 * William Jolitz.
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 *    notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 *    notice, this list of conditions and the following disclaimer in the
17 *    documentation and/or other materials provided with the distribution.
18 * 3. Neither the name of the University nor the names of its contributors
19 *    may be used to endorse or promote products derived from this software
20 *    without specific prior written permission.
21 *
22 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
23 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
24 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
25 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
26 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
27 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
28 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
30 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
31 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
32 * SUCH DAMAGE.
33 *
34 *        from: @(#)setjmp.s  5.1 (Berkeley) 4/23/90"
35 */
36
37#include <machine/asm.h>
38#if defined(LIBC_SCCS)
39          RCSID("$NetBSD: sigsetjmp.S,v 1.20 2025/05/03 19:55:32 riastradh Exp $")
40#endif
41
42/*
43 * sigsetjmp(sigjmp_buf env@esp[4,8), savemask@esp[8,12))
44 *
45 * ELF symbol: __sigsetjmp14, because the size of sigjmp_buf changed on
46 * some platforms in 1.4.
47 */
48ENTRY(__sigsetjmp14)
49          /*
50           * Save the callee-saves registers: %ebp, %ebx, %edi, %esi,
51           * plus %esp and the return address on the stack since it
52           * will be overwritten if the caller makes any subroutine
53           * calls before siglongjmp.
54           */
55          movl      4(%esp),%ecx                  /* ecx := env */
56          movl      0(%esp),%edx                  /* edx := return address */
57          movl      %edx,0(%ecx)
58          movl      %ebx,4(%ecx)
59          movl      %esp,8(%ecx)
60          movl      %ebp,12(%ecx)
61          movl      %esi,16(%ecx)
62          movl      %edi,20(%ecx)
63
64          /* Check if we should save the signal mask, and remember it. */
65          movl      8(%esp),%eax                  /* eax := savemask */
66          movl      %eax,40(%ecx)
67          testl     %eax,%eax           /* savemask == 0? */
68          jz        2f                            /* jump if savemask == 0 */
69
70          /* Get the signal mask. */
71          leal      24(%ecx),%edx
72
73          PIC_PROLOGUE
74          pushl     %edx                          /* oset (signal mask saved to) */
75          pushl     $0                            /* set := NULL */
76          pushl     $0                            /* how := 0 (ignored) */
77          call      PIC_PLT(_C_LABEL(__sigprocmask14))
78          addl      $12,%esp            /* pop sigprocmask args */
79          PIC_EPILOGUE
80
812:        xorl      %eax,%eax           /* return 0 first time around */
82          ret
83END(__sigsetjmp14)
84
85/*
86 * siglongjmp(sigjmp_buf env@esp[4,8), int val@[8,12))
87 *
88 * ELF symbol: __siglongjmp14, because the size of sigjmp_buf changed
89 * on some platforms in 1.4.
90 */
91ENTRY(__siglongjmp14)
92          /*
93           * Restore the callee-saves registers: %ebp, %ebx, %edi, %esi,
94           * plus %esp and the return address on the stack.
95           */
96          movl      4(%esp),%edx                  /* edx := env */
97          movl      8(%esp),%eax                  /* eax := val */
98          movl      0(%edx),%ecx                  /* ecx := return address */
99          movl      4(%edx),%ebx
100          movl      8(%edx),%esp
101          movl      12(%edx),%ebp
102          movl      16(%edx),%esi
103          movl      20(%edx),%edi
104          movl      %ecx,0(%esp)                  /* restore return address */
105
106          /* Check to see if we need to restore the signal mask. */
107          cmpl      $0,40(%edx)                   /* savemask == 0 */
108          jz        2f                            /* jump if savemask == 0 */
109
110          /* Restore the signal mask. */
111          leal      24(%edx),%edx
112
113          pushl     %eax                          /* save val@eax */
114
115          PIC_PROLOGUE
116          pushl     $0                            /* oset := NULL */
117          pushl     %edx                          /* set (signal mask restored from) */
118          pushl     $3                            /* how := SIG_SETMASK */
119          call      PIC_PLT(_C_LABEL(__sigprocmask14))
120          addl      $12,%esp            /* pop sigprocmask args */
121          PIC_EPILOGUE
122
123          popl      %eax                          /* restore val@eax */
124
1252:        testl     %eax,%eax           /* val == 0? */
126          jz        3f                            /* jump if val == 0 */
127          ret                                     /* return val@eax */
128
1293:        incl      %eax                          /* val@eax := 1 */
130          ret                                     /* return val@eax */
131END(__siglongjmp14)
132