1/*-
2 * Copyright (c) 2013 The NetBSD Foundation, Inc.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to The NetBSD Foundation
6 * by Matt Thomas of 3am Software Foundry.
7 *
8 * Redistribution and use in source and binary forms, with or without
9 * modification, are permitted provided that the following conditions
10 * are met:
11 * 1. Redistributions of source code must retain the above copyright
12 *    notice, this list of conditions and the following disclaimer.
13 * 2. Redistributions in binary form must reproduce the above copyright
14 *    notice, this list of conditions and the following disclaimer in the
15 *    documentation and/or other materials provided with the distribution.
16 *
17 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
18 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
19 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
20 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
21 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
22 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
23 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
24 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
25 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
26 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
27 * POSSIBILITY OF SUCH DAMAGE.
28 */
29#include <machine/asm.h>
30
31RCSID("$NetBSD: strcpy_naive.S,v 1.8 2017/01/14 04:54:42 christos Exp $")
32
33#ifdef _LIBC
34#ifdef STRLCPY
35WEAK_ALIAS(strlcpy, _strlcpy)
36#define strlcpy _strlcpy
37#endif
38#endif
39
40/*
41 * These are "naive" versions of the str*cpy routines designed to be simple
42 * and small.
43 */
44
45#if defined(STRLCPY)
46/* LINTSTUB: size_t strlcpy(char *, const char *, size_t) */
47ENTRY(strlcpy)
48          add       ip, r1, #1                    /* save src pointer (+ NUL) */
49          subs      r2, r2, #1                    /* make sure there's room for a NUL */
50          blt       3f                            /*   no room, do the strlen */
51          add       r2, r2, r0                    /* get end of dst */
521:        cmp       r0, r2                        /* room for another char? */
53          beq       2f                            /*   no, write NUL and do the strlen */
54          ldrb      r3, [r1], #1                  /* read a byte */
55          strb      r3, [r0], #1                  /* write a byte */
56          teq       r3, #0                        /* was it a NUL? */
57          bne       1b                            /*   no, do next byte */
58          b         4f                            /*   yes, end of string, so return */
592:        mov       r3, #0                        /* NUL */
60          strb      r3, [r0]            /* write to end of string */
613:        ldrb      r3, [r1], #1                  /* read a byte */
62          teq       r3, #0                        /* was it a NUL? */
63          bne       3b                            /*   no, get next byte */
644:        sub       r0, r1, ip                    /* return length of src string */
65          RET
66END(strlcpy)
67#elif defined(STRNCPY)
68/* LINTSTUB: char * strncpy(char *, const char *, size_t) */
69ENTRY(strncpy)
70          mov       ip, r0                        /* we want to preserve r0 */
71          add       r2, r2, r0                    /* get end of dst buffer */
721:        cmp       ip, r2                        /* are at the end of dst already? */
73          RETc(eq)                      /*   yes, just return. */
74          ldrb      r3, [r1], #1                  /* read a byte */
75          strb      r3, [ip], #1                  /* write a byte */
76          teq       r3, #0                        /* was it a NUL? */
77          bne       1b                            /*   no, try next byte */
782:        cmp       ip, r2                        /* are at the end of dst already? */
79          strblt    r3, [ip], #1                  /*   no, write a NUL */
80          blt       2b                            /*       until dst is filled */
813:        RET                                     /* return dst pointer */
82END(strncpy)
83#else
84/* LINTSTUB: char * strcpy(char *, const char *) */
85ENTRY(strcpy)
86          mov       ip, r0                        /* we want to preserve r0 */
871:        ldrb      r3, [r1], #1                  /* read a byte */
88          strb      r3, [ip], #1                  /* write a byte */
89          teq       r3, #0                        /* was it a NUL? */
90          bne       1b                            /*   no, try next byte */
91          RET                                     /* return dst pointer */
92END(strcpy)
93#endif
94