1/*        $NetBSD: atomic_or_8.S,v 1.5 2021/07/28 07:32:20 skrll Exp $          */
2
3/*-
4 * Copyright (c) 2013 The NetBSD Foundation, Inc.
5 * All rights reserved.
6 *
7 * This code is derived from software contributed to The NetBSD Foundation
8 * by Matt Thomas <matt@3am-software.com>
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 *    notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 *    notice, this list of conditions and the following disclaimer in the
17 *    documentation and/or other materials provided with the distribution.
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
20 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
21 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
22 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
23 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29 * POSSIBILITY OF SUCH DAMAGE.
30 */
31
32#include "atomic_op_asm.h"
33
34#if defined(_ARM_ARCH_6)
35
36ENTRY_NP(_atomic_or_8)
37          mov       ip, r0
381:        ldrexb    r0, [ip]            /* load old value (to be returned) */
39          orrs      r3, r0, r1                    /* calculate new value */
40          strexb    r2, r3, [ip]                  /* try to store */
41          cmp       r2, #0                        /*   succeed? */
42          bne       1b                            /*     no, try again */
43          RET                                     /* return old value */
44END(_atomic_or_8)
45
46ATOMIC_OP_ALIAS(atomic_or_8,_atomic_or_8)
47ATOMIC_OP_ALIAS(atomic_or_char,_atomic_or_8)
48CRT_ALIAS(__atomic_fetch_or_1,_atomic_or_8)
49STRONG_ALIAS(_atomic_or_char,_atomic_or_8)
50
51ENTRY_NP(__sync_fetch_and_or_1)
52          push      {r4, lr}
53          DMB
54          bl        _atomic_or_8
55          DMB
56          pop       {r4, pc}
57END(__sync_fetch_and_or_1)
58
59
60ENTRY_NP(_atomic_or_8_nv)
61          mov       ip, r0                        /* need r0 for return value */
621:        ldrexb    r0, [ip]            /* load old value */
63          orrs      r0, r0, r1                    /* calculate new value (return value) */
64          strexb    r2, r0, [ip]                  /* try to store */
65          cmp       r2, #0                        /*   succeed? */
66          bne       1b                            /*     no, try again? */
67          RET                                     /* return new value */
68END(_atomic_or_8_nv)
69
70ATOMIC_OP_ALIAS(atomic_or_8_nv,_atomic_or_8_nv)
71ATOMIC_OP_ALIAS(atomic_or_char_nv,_atomic_or_8_nv)
72STRONG_ALIAS(_atomic_or_char_nv,_atomic_or_8_nv)
73
74ENTRY_NP(__sync_or_and_fetch_1)
75          push      {r4, lr}
76          DMB
77          bl        _atomic_or_8_nv
78          DMB
79          pop       {r4, pc}
80END(__sync_or_and_fetch_1)
81
82#endif /* _ARM_ARCH_6 */
83