1dnl $MirOS: src/gnu/usr.bin/binutils/bfd/configure.in,v 1.7 2006/07/01 13:51:20 tg Exp $
2dnl
3dnl Process this file with autoconf to produce a configure script.
4dnl
5
6AC_PREREQ(2.59)
7AC_INIT
8AC_CONFIG_SRCDIR([libbfd.c])
9
10AC_CANONICAL_TARGET
11AC_ISC_POSIX
12
13AM_INIT_AUTOMAKE(bfd, 050707)
14
15dnl These must be called before AM_PROG_LIBTOOL, because it may want
16dnl to call AC_CHECK_PROG.
17AC_CHECK_TOOL(AR, ar)
18AC_CHECK_TOOL(RANLIB, ranlib, :)
19
20dnl Default to a non shared library.  This may be overridden by the
21dnl configure option --enable-shared.
22AM_DISABLE_SHARED
23
24AC_GNU_SOURCE
25AM_PROG_LIBTOOL
26
27AC_ARG_ENABLE(64-bit-bfd,
28[  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
29[case "${enableval}" in
30  yes)  want64=true  ;;
31  no)   want64=false ;;
32  *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
33esac],[want64=false])dnl
34AC_ARG_ENABLE(targets,
35[  --enable-targets        alternative target configurations],
36[case "${enableval}" in
37  yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
38            ;;
39  no)       enable_targets= ;;
40  *)        enable_targets=$enableval ;;
41esac])dnl
42AC_ARG_ENABLE(commonbfdlib,
43[  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
44[case "${enableval}" in
45  yes) commonbfdlib=true ;;
46  no)  commonbfdlib=false ;;
47  *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
48esac])dnl
49AC_ARG_WITH(mmap,
50[  --with-mmap             try using mmap for BFD input files if available],
51[case "${withval}" in
52  yes)  want_mmap=true ;;
53  no)   want_mmap=false ;;
54  *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
55esac],[want_mmap=false])dnl
56
57AC_ARG_ENABLE(secureplt,
58[  --enable-secureplt      Default to creating read-only plt entries],
59[case "${enableval}" in
60  yes)  use_secureplt=true  ;;
61  no)   use_secureplt=false ;;
62  *)    AC_MSG_ERROR(bad value ${enableval} for secureplt option) ;;
63esac],[use_secureplt=false])dnl
64if test $use_secureplt = true; then
65  AC_DEFINE(USE_SECUREPLT, 1,
66    [Define if we should default to creating read-only plt entries])
67fi
68
69AM_BINUTILS_WARNINGS
70
71AM_CONFIG_HEADER(config.h:config.in)
72
73if test -z "$target" ; then
74    AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
75fi
76
77AM_MAINTAINER_MODE
78AM_INSTALL_LIBBFD
79AC_EXEEXT
80
81host64=false
82target64=false
83bfd_default_target_size=32
84
85# host stuff:
86
87AC_PROG_CC
88
89# Permit host specific settings.
90. ${srcdir}/configure.host
91
92AC_SUBST(HDEFINES)
93AC_PROG_INSTALL
94
95BFD_HOST_64BIT_LONG=0
96BFD_HOST_LONG_LONG=0
97BFD_HOST_64_BIT_DEFINED=0
98BFD_HOST_64_BIT=
99BFD_HOST_U_64_BIT=
100
101AC_MSG_CHECKING([for long long])
102AC_CACHE_VAL(bfd_cv_has_long_long,
103[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
104AC_MSG_RESULT($bfd_cv_has_long_long)
105if test $bfd_cv_has_long_long = yes; then
106  BFD_HOST_LONG_LONG=1
107  AC_CHECK_SIZEOF(long long)
108fi
109
110AC_CHECK_SIZEOF(long)
111if test "x${ac_cv_sizeof_long}" = "x8"; then
112  host64=true
113  BFD_HOST_64BIT_LONG=1
114  test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
115  test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
116elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
117  test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
118  test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
119fi
120
121if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
122  BFD_HOST_64_BIT_DEFINED=1
123  BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
124  BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
125fi
126
127AC_SUBST(BFD_HOST_64BIT_LONG)
128AC_SUBST(BFD_HOST_LONG_LONG)
129AC_SUBST(BFD_HOST_64_BIT_DEFINED)
130AC_SUBST(BFD_HOST_64_BIT)
131AC_SUBST(BFD_HOST_U_64_BIT)
132
133BFD_CC_FOR_BUILD
134
135AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
136AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
137AC_HEADER_TIME
138AC_HEADER_DIRENT
139ACX_HEADER_STRING
140AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
141AC_CHECK_FUNCS(strtoull)
142
143AC_CHECK_DECLS(basename)
144AC_CHECK_DECLS(ftello)
145AC_CHECK_DECLS(ftello64)
146AC_CHECK_DECLS(fseeko)
147AC_CHECK_DECLS(fseeko64)
148
149BFD_BINARY_FOPEN
150
151AC_CHECK_DECLS(ffs)
152AC_CHECK_DECLS(free)
153AC_CHECK_DECLS(getenv)
154AC_CHECK_DECLS(malloc)
155AC_CHECK_DECLS(realloc)
156AC_CHECK_DECLS(stpcpy)
157AC_CHECK_DECLS(strstr)
158AC_CHECK_DECLS(snprintf)
159AC_CHECK_DECLS(vsnprintf)
160
161# If we are configured native, pick a core file support file.
162COREFILE=
163COREFLAG=
164TRAD_HEADER=
165if test "${target}" = "${host}"; then
166  case "${host}" in
167  alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
168	COREFILE=''
169	;;
170  alpha*-*-linux-*)
171	COREFILE=trad-core.lo
172	TRAD_HEADER='"hosts/alphalinux.h"'
173	;;
174  alpha*-*-netbsd* | alpha*-*-openbsd*)
175	COREFILE=netbsd-core.lo
176	;;
177  alpha*-*-*)		COREFILE=osf-core.lo ;;
178  arm-*-freebsd* | arm-*-kfreebsd*-gnu)
179			COREFILE='' ;;
180  arm-*-netbsd*)	COREFILE=netbsd-core.lo ;;
181  arm-*-riscix)		COREFILE=trad-core.lo ;;
182  hppa*-*-hpux*)	COREFILE=hpux-core.lo ;;
183  hppa*-*-hiux*)	COREFILE=hpux-core.lo ;;
184  hppa*-*-mpeix*)	COREFILE=hpux-core.lo ;;
185  hppa*-*-bsd*)		COREFILE="hpux-core.lo hppabsd-core.lo"
186			COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
187  hppa*-*-netbsd* | hppa*-*-openbsd*)
188	COREFILE=netbsd-core.lo
189	;;
190
191  i370-*-*)
192	COREFILE=trad-core.lo
193	TRAD_HEADER='"hosts/i370linux.h"'
194	;;
195
196  i386-*-mirbsd*)
197	COREFILE=netbsd-core.lo
198	;;
199
200changequote(,)dnl
201  i[3-7]86-sequent-bsd*)
202changequote([,])dnl
203	COREFILE=trad-core.lo
204	TRAD_HEADER='"hosts/symmetry.h"'
205	;;
206changequote(,)dnl
207  i[3-7]86-sequent-sysv4*) ;;
208  i[3-7]86-sequent-sysv*)
209changequote([,])dnl
210	COREFILE=trad-core.lo
211	TRAD_HEADER='"hosts/symmetry.h"'
212	;;
213changequote(,)dnl
214  i[3-7]86-*-bsdi)
215changequote([,])dnl
216	COREFILE=
217	;;
218changequote(,)dnl
219  i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
220changequote([,])dnl
221	COREFILE=trad-core.lo
222	TRAD_HEADER='"hosts/i386bsd.h"'
223	;;
224changequote(,)dnl
225  i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
226changequote([,])dnl
227	COREFILE=''
228	TRAD_HEADER='"hosts/i386bsd.h"'
229	;;
230changequote(,)dnl
231  i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
232changequote([,])dnl
233	COREFILE=netbsd-core.lo
234	;;
235changequote(,)dnl
236  i[3-7]86-esix-sysv3*)
237changequote([,])dnl
238	COREFILE=trad-core.lo
239	TRAD_HEADER='"hosts/esix.h"'
240	;;
241changequote(,)dnl
242  i[3-7]86-*-sco3.2v5*)
243changequote([,])dnl
244	COREFILE=sco5-core.lo
245	;;
246changequote(,)dnl
247  i[3-7]86-*-sco* | i[3-7]86-*-isc*)
248changequote([,])dnl
249	COREFILE=trad-core.lo
250	TRAD_HEADER='"hosts/i386sco.h"'
251	;;
252changequote(,)dnl
253  i[3-7]86-*-mach3*)
254changequote([,])dnl
255	COREFILE=trad-core.lo
256	TRAD_HEADER='"hosts/i386mach3.h"'
257	;;
258changequote(,)dnl
259  i[3-7]86-*-linux-*)
260changequote([,])dnl
261	COREFILE=trad-core.lo
262	TRAD_HEADER='"hosts/i386linux.h"'
263	;;
264changequote(,)dnl
265  i[3-7]86-*-isc*)	COREFILE=trad-core.lo ;;
266  i[3-7]86-*-aix*)	COREFILE=aix386-core.lo ;;
267changequote([,])dnl
268  i860-*-mach3* | i860-*-osf1*)
269	COREFILE=trad-core.lo
270	TRAD_HEADER='"hosts/i860mach3.h"'
271	;;
272  mips-*-netbsd* | mips*-*-openbsd*)
273	COREFILE=netbsd-core.lo
274	;;
275  mips-dec-*)
276	COREFILE=trad-core.lo
277	TRAD_HEADER='"hosts/decstation.h"'
278	;;
279  mips-sgi-irix4*)	COREFILE=irix-core.lo ;;
280  mips-sgi-irix5*)	COREFILE=irix-core.lo ;;
281  mips-sgi-irix6*)	COREFILE=irix-core.lo ;;
282  mips-*-sysv4*)	;;
283  mips-*-sysv* | mips-*-riscos*)
284	COREFILE=trad-core.lo
285	TRAD_HEADER='"hosts/riscos.h"'
286	;;
287  mips-sony-bsd*)
288	COREFILE=trad-core.lo
289	TRAD_HEADER='"hosts/news-mips.h"'
290	;;
291  m68*-bull*-sysv*)
292	COREFILE=trad-core.lo
293	TRAD_HEADER='"hosts/dpx2.h"'
294	;;
295  m68*-hp-hpux*)	COREFILE=hpux-core.lo ;;
296  m68*-hp-bsd*)
297	COREFILE=trad-core.lo
298	TRAD_HEADER='"hosts/hp300bsd.h"'
299	;;
300  m68*-*-linux-*)
301	COREFILE=trad-core.lo
302	TRAD_HEADER='"hosts/m68klinux.h"'
303	;;
304  m68*-motorola-sysv*)
305	COREFILE=trad-core.lo
306	TRAD_HEADER='"hosts/delta68.h"'
307	;;
308  m68*-sony-*)
309	COREFILE=trad-core.lo
310	TRAD_HEADER='"hosts/news.h"'
311	;;
312  m68*-*-netbsd* | m68*-*-openbsd*)
313	COREFILE=netbsd-core.lo
314	;;
315  m68*-apple-aux*)
316	COREFILE=trad-core.lo
317	TRAD_HEADER='"hosts/m68kaux.h"'
318	;;
319  m88*-*-sysv4*)
320	;;
321  m88*-motorola-sysv*)
322	COREFILE=ptrace-core.lo
323	;;
324  m88*-*-mach3*)
325	COREFILE=trad-core.lo
326	TRAD_HEADER='"hosts/m88kmach3.h"'
327	;;
328  m88*-*-openbsd*)
329	COREFILE=netbsd-core.lo
330	;;
331  ns32k-pc532-mach)
332	COREFILE=trad-core.lo
333	TRAD_HEADER='"hosts/pc532mach.h"'
334	;;
335  ns32k-*-netbsd* | ns32k-*-openbsd*)
336	COREFILE=netbsd-core.lo
337	;;
338  rs6000-*-lynx*)
339  	COREFILE=lynx-core.lo
340	;;
341  rs6000-*-aix5.* | powerpc-*-aix5.*)
342        COREFILE=rs6000-core.lo
343	COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
344	;;
345changequote(,)dnl
346  rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
347changequote([,])dnl
348        COREFILE=rs6000-core.lo
349	COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
350	# Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
351	# have c_impl as a member of struct core_dumpx
352	AC_MSG_CHECKING([for c_impl in struct core_dumpx])
353	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
354	    [Define if struct core_dumpx has member c_impl])
355	  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
356	;;
357  rs6000-*-aix4*)	COREFILE=rs6000-core.lo ;;
358  rs6000-*-*)		COREFILE=rs6000-core.lo ;;
359  powerpc-*-aix4*)	COREFILE=rs6000-core.lo ;;
360  powerpc-*-aix*)	COREFILE=rs6000-core.lo ;;
361  powerpc-*-beos*)	;;
362  powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
363		        COREFILE='' ;;
364  powerpc-*-netbsd*)	COREFILE=netbsd-core.lo ;;
365  powerpc-*-*bsd*)	COREFILE=netbsd-core.lo ;;
366  s390*-*-*)            COREFILE=trad-core.lo ;;
367  sh*-*-netbsd*)	COREFILE=netbsd-core.lo ;;
368  sparc-*-mirbsd* | sparc-*-netbsd* | sparc*-*-openbsd*)
369	COREFILE=netbsd-core.lo
370	;;
371  tahoe-*-*)
372	COREFILE=trad-core.lo
373	TRAD_HEADER='"hosts/tahoe.h"'
374	;;
375  vax-*-netbsd* | vax-*-openbsd*)
376  	COREFILE=netbsd-core.lo
377	;;
378  vax-*-ultrix2*)
379	COREFILE=trad-core.lo
380	TRAD_HEADER='"hosts/vaxult2.h"'
381	;;
382  vax-*-ultrix*)
383	COREFILE=trad-core.lo
384	TRAD_HEADER='"hosts/vaxult2.h"'
385	;;
386  vax-*-linux-*)
387	COREFILE=trad-core.lo
388	TRAD_HEADER='"hosts/vaxlinux.h"'
389	;;
390  vax-*-*)
391	COREFILE=trad-core.lo
392	TRAD_HEADER='"hosts/vaxbsd.h"'
393	;;
394  x86_64-*-netbsd* | x86_64-*-openbsd*)
395	COREFILE=netbsd-core.lo
396	;;
397  esac
398
399  case "$COREFILE" in
400  aix386-core.lo)	COREFLAG=-DAIX386_CORE ;;
401  hppabsd-core.lo)	COREFLAG=-DHPPABSD_CORE ;;
402  hpux-core.lo)		COREFLAG=-DHPUX_CORE ;;
403  irix-core.lo)		COREFLAG=-DIRIX_CORE ;;
404  lynx-core.lo)		COREFLAG=-DLYNX_CORE ;;
405  netbsd-core.lo)	COREFLAG=-DNETBSD_CORE ;;
406  osf-core.lo)		COREFLAG=-DOSF_CORE ;;
407  ptrace-core.lo)	COREFLAG=-DPTRACE_CORE ;;
408  rs6000-core.lo)	COREFLAG="$COREFLAG -DAIX_CORE" ;;
409  sco5-core.lo)		COREFLAG="$COREFLAG -DSCO5_CORE" ;;
410  trad-core.lo)		COREFLAG="$COREFLAG -DTRAD_CORE" ;;
411  esac
412
413  # ELF corefile support has several flavors, but all of
414  # them use something called <sys/procfs.h>
415  AC_CHECK_HEADERS(sys/procfs.h)
416  if test "$ac_cv_header_sys_procfs_h" = yes; then
417    BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
418    BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
419    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
420    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
421    BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
422    BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
423    BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
424    BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
425    BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
426    BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
427    BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
428    BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
429    BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
430    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
431    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
432    BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
433  fi
434fi
435AC_SUBST(COREFILE)
436AC_SUBST(COREFLAG)
437if test -n "$TRAD_HEADER"; then
438  AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
439    [Name of host specific header file to include in trad-core.c.])
440fi
441
442# Horrible hacks to build DLLs on Windows.
443WIN32LDFLAGS=
444WIN32LIBADD=
445case "${host}" in
446*-*-cygwin*)
447  if test "$enable_shared" = "yes"; then
448    WIN32LDFLAGS="-no-undefined"
449    WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
450  fi
451  ;;
452*-*-linux*)
453  # We borrow WIN32LIBADD so that the shared libbfd won't depend on
454  # libiberty.a.
455  case "${host}" in
456  mips*-*-linux*)
457    # Linux/MIPS uses PIC by default.
458    if test "$enable_shared" = "yes"; then
459      WIN32LIBADD="-L../libiberty -liberty"
460    fi
461    ;;
462  *)
463changequote(,)dnl
464    x=`sed -n -e 's/^[ 	]*PICFLAG[ 	]*=[ 	]*//p' < ../libiberty/Makefile | sed -n '$p'`
465changequote([,])dnl
466    if test -n "$x"; then
467      WIN32LIBADD="-L../libiberty/pic -liberty"
468    fi
469  ;;
470  esac
471  ;;
472esac
473AC_SUBST(WIN32LDFLAGS)
474AC_SUBST(WIN32LIBADD)
475
476# target stuff:
477
478# Canonicalize the secondary target names.
479if test -n "$enable_targets" ; then
480    for targ in `echo $enable_targets | sed 's/,/ /g'`
481    do
482	result=`$ac_config_sub $targ 2>/dev/null`
483	if test -n "$result" ; then
484	    canon_targets="$canon_targets $result"
485	else
486	    # Allow targets that config.sub doesn't recognize, like "all".
487	    canon_targets="$canon_targets $targ"
488	fi
489    done
490fi
491
492all_targets=false
493defvec=
494selvecs=
495assocvecs=
496selarchs=
497TDEFINES=
498for targ in $target $canon_targets
499do
500    if test "x$targ" = "xall"; then
501        all_targets=true
502	assocvecs="$assocvecs $targ_defvec $targ_selvecs"
503    else
504	. $srcdir/config.bfd
505	if test "x$targ" = "x$target"; then
506	    defvec=$targ_defvec
507	fi
508	selvecs="$selvecs $targ_defvec $targ_selvecs"
509	selarchs="$selarchs $targ_archs"
510	TDEFINES="$TDEFINES $targ_cflags"
511    fi
512done
513AC_SUBST(TDEFINES)
514
515# This processing still needs to be done if we're to decide properly whether
516# 64-bit support needs to be compiled in.  Currently, it will be included if
517# the default or any other explicitly requested target requires it; it
518# will not be included on a 32-bit host if no 64-bit target is requested, and
519# no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
520# used.
521
522# uniq the default and selected vectors in all the configured targets.
523f=""
524for i in $selvecs ; do
525    case " $f " in
526    *" $i "*) ;;
527    *) f="$f $i" ;;
528    esac
529done
530selvecs="$f"
531
532
533# uniq the associated vectors in all the configured targets.
534f=""
535for i in $assocvecs ; do
536    case " $f " in
537    *" $i "*) ;;
538    *) f="$f $i" ;;
539    esac
540done
541assocvecs="$f"
542
543
544# uniq the architectures in all the configured targets.
545f=""
546for i in $selarchs ; do
547    case " $f " in
548    *" $i "*) ;;
549    *) f="$f $i" ;;
550    esac
551done
552selarchs="$f"
553
554# Target backend .o files.
555tb=
556
557elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
558
559for vec in $selvecs
560do
561    target_size=32
562    case "$vec" in
563    # This list is alphabetized to make it easy to compare
564    # with the two vector lists in targets.c.  For the same reason,
565    # use one entry per line, even though this leads to long lines.
566    a29kcoff_big_vec)		tb="$tb coff-a29k.lo cofflink.lo" ;;
567    a_out_adobe_vec)		tb="$tb aout-adobe.lo aout32.lo" ;;
568    aix5coff64_vec)		tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
569    aout0_big_vec)		tb="$tb aout0.lo aout32.lo" ;;
570    aout_arm_big_vec)		tb="$tb aout-arm.lo aout32.lo" ;;
571    aout_arm_little_vec)	tb="$tb aout-arm.lo aout32.lo" ;;
572    apollocoff_vec)		tb="$tb coff-apollo.lo" ;;
573    arm_epoc_pe_big_vec)	tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
574    arm_epoc_pe_little_vec)	tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
575    arm_epoc_pei_big_vec)	tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
576    arm_epoc_pei_little_vec)	tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
577    armcoff_big_vec)		tb="$tb coff-arm.lo cofflink.lo " ;;
578    armcoff_little_vec)		tb="$tb coff-arm.lo cofflink.lo " ;;
579    armnetbsd_vec)		tb="$tb armnetbsd.lo aout32.lo" ;;
580    armpe_big_vec)		tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
581    armpe_little_vec)		tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
582    armpei_big_vec)		tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
583    armpei_little_vec)		tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
584    b_out_vec_big_host)		tb="$tb bout.lo aout32.lo" ;;
585    b_out_vec_little_host)	tb="$tb bout.lo aout32.lo" ;;
586    bfd_efi_app_ia32_vec)	tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
587    bfd_efi_app_ia64_vec)	tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
588    bfd_elf32_am33lin_vec)	tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
589    bfd_elf32_avr_vec)		tb="$tb elf32-avr.lo elf32.lo $elf" ;;
590    bfd_elf32_big_generic_vec) 	tb="$tb elf32-gen.lo elf32.lo $elf" ;;
591    bfd_elf32_bigarc_vec)	tb="$tb elf32-arc.lo elf32.lo $elf" ;;
592    bfd_elf32_bigarm_vec)	tb="$tb elf32-arm.lo elf32.lo $elf" ;;
593    bfd_elf32_bigarm_symbian_vec)
594                                tb="$tb elf32-arm.lo elf32.lo $elf" ;;
595    bfd_elf32_bigarm_vxworks_vec)
596                                tb="$tb elf32-arm.lo elf32.lo $elf" ;;
597    bfd_elf32_bigmips_vec) 	tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
598    bfd_elf32_cr16c_vec)	tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
599    bfd_elf32_cris_vec)		tb="$tb elf32-cris.lo elf32.lo $elf" ;;
600    bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
601    bfd_elf32_d10v_vec)		tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
602    bfd_elf32_d30v_vec)		tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
603    bfd_elf32_dlx_big_vec)	tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
604    bfd_elf32_fr30_vec)		tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
605    bfd_elf32_frv_vec)		tb="$tb elf32-frv.lo elf32.lo $elf" ;;
606    bfd_elf32_frvfdpic_vec)	tb="$tb elf32-frv.lo elf32.lo $elf" ;;
607    bfd_elf32_h8300_vec)	tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
608    bfd_elf32_hppa_linux_vec)	tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
609    bfd_elf32_hppa_nbsd_vec)	tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
610    bfd_elf32_hppa_vec)		tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
611    bfd_elf32_i370_vec)		tb="$tb elf32-i370.lo elf32.lo $elf" ;;
612    bfd_elf32_i386_freebsd_vec)	tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
613    bfd_elf32_i386_vxworks_vec)	tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
614    bfd_elf32_i386_vec)		tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
615    bfd_elf32_i860_little_vec)	tb="$tb elf32-i860.lo elf32.lo $elf" ;;
616    bfd_elf32_i860_vec)		tb="$tb elf32-i860.lo elf32.lo $elf" ;;
617    bfd_elf32_i960_vec)		tb="$tb elf32-i960.lo elf32.lo $elf" ;;
618    bfd_elf32_ia64_big_vec)	tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
619    bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
620    bfd_elf32_ip2k_vec)		tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
621    bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
622    bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
623    bfd_elf32_littlearc_vec)	tb="$tb elf32-arc.lo elf32.lo $elf" ;;
624    bfd_elf32_littlearm_symbian_vec)
625                                tb="$tb elf32-arm.lo elf32.lo $elf" ;;
626    bfd_elf32_littlearm_vxworks_vec)
627                                tb="$tb elf32-arm.lo elf32.lo $elf" ;;
628    bfd_elf32_littlearm_vec)	tb="$tb elf32-arm.lo elf32.lo $elf" ;;
629    bfd_elf32_littlemips_vec) 	tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
630    bfd_elf32_m32r_vec)		tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
631    bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
632    bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
633    bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
634    bfd_elf32_m68hc11_vec)	tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
635    bfd_elf32_m68hc12_vec)	tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
636    bfd_elf32_m68k_vec)		tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
637    bfd_elf32_m88k_vec)		tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
638    bfd_elf32_mcore_big_vec)	tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
639    bfd_elf32_mcore_little_vec)	tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
640    bfd_elf32_mn10200_vec)	tb="$tb elf-m10200.lo elf32.lo $elf" ;;
641    bfd_elf32_mn10300_vec)	tb="$tb elf-m10300.lo elf32.lo $elf" ;;
642    bfd_elf32_ms1_vec)          tb="$tb elf32-ms1.lo elf32.lo $elf" ;;
643    bfd_elf32_msp430_vec)	tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
644    bfd_elf32_nbigmips_vec)	tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
645    bfd_elf32_nlittlemips_vec)	tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
646    bfd_elf32_ntradbigmips_vec)	tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
647    bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
648    bfd_elf32_openrisc_vec)	tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
649    bfd_elf32_or32_big_vec)	tb="$tb elf32-or32.lo elf32.lo $elf" ;;
650    bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
651    bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
652    bfd_elf32_powerpc_vec)	tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
653    bfd_elf32_powerpcle_vec)	tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
654    bfd_elf32_powerpc_vxworks_vec) tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
655    bfd_elf32_s390_vec)		tb="$tb elf32-s390.lo elf32.lo $elf" ;;
656    # FIXME: We include cofflink.lo not because it's needed for
657    # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
658    # which needs it but does not list it.  Should be fixed in right place.
659    bfd_elf32_sh64_vec)		tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
660    bfd_elf32_sh64l_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
661    bfd_elf32_sh64lin_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
662    bfd_elf32_sh64blin_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
663    bfd_elf32_sh64lnbsd_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
664    bfd_elf32_sh64nbsd_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
665    bfd_elf32_sh_vec)		tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
666    bfd_elf32_shblin_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
667    bfd_elf32_shl_vec)		tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
668    bfd_elf32_shl_symbian_vec)	tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
669    bfd_elf32_shlin_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
670    bfd_elf32_shlnbsd_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
671    bfd_elf32_shnbsd_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
672    bfd_elf32_sparc_vec)	tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
673    bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
674    bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
675    bfd_elf32_us_cris_vec)	tb="$tb elf32-cris.lo elf32.lo $elf" ;;
676    bfd_elf32_v850_vec)		tb="$tb elf32-v850.lo elf32.lo $elf" ;;
677    bfd_elf32_vax_vec)		tb="$tb elf32-vax.lo elf32.lo $elf" ;;
678    bfd_elf32_xstormy16_vec)	tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
679    bfd_elf32_xtensa_le_vec)	tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
680    bfd_elf32_xtensa_be_vec)	tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
681    bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
682    bfd_elf64_alpha_vec)	tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
683    bfd_elf64_big_generic_vec) 	tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
684    bfd_elf64_bigmips_vec) 	tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
685    bfd_elf64_hppa_linux_vec)	tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
686    bfd_elf64_hppa_vec)		tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
687    bfd_elf64_ia64_big_vec)	tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
688    bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
689    bfd_elf64_ia64_little_vec)	tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
690    bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
691    bfd_elf64_littlemips_vec) 	tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
692    bfd_elf64_mmix_vec) 	tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
693    bfd_elf64_powerpc_vec)	tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
694    bfd_elf64_powerpcle_vec)	tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
695    bfd_elf64_s390_vec)		tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
696    bfd_elf64_sh64_vec)		tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
697    bfd_elf64_sh64l_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
698    bfd_elf64_sh64lin_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
699    bfd_elf64_sh64blin_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
700    bfd_elf64_sh64lnbsd_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
701    bfd_elf64_sh64nbsd_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
702    bfd_elf64_sparc_vec)	tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
703    bfd_elf64_tradbigmips_vec)	tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
704    bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
705    bfd_elf64_x86_64_vec)	tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
706    bfd_mmo_vec)		tb="$tb mmo.lo" target_size=64 ;;
707    bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
708    bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
709    bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
710    bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
711    cris_aout_vec)		tb="$tb aout-cris.lo" ;;
712    demo_64_vec)		tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
713    ecoff_big_vec)		tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
714    ecoff_biglittle_vec)	tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
715    ecoff_little_vec)		tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
716    ecoffalpha_little_vec)	tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
717    go32coff_vec)		tb="$tb coff-go32.lo cofflink.lo" ;;
718    go32stubbedcoff_vec)	tb="$tb coff-stgo32.lo cofflink.lo" ;;
719    h8300coff_vec)		tb="$tb coff-h8300.lo reloc16.lo" ;;
720    h8500coff_vec)		tb="$tb coff-h8500.lo reloc16.lo" ;;
721    host_aout_vec)		tb="$tb host-aout.lo aout32.lo" ;;
722    hp300bsd_vec)		tb="$tb hp300bsd.lo aout32.lo" ;;
723    hp300hpux_vec)		tb="$tb hp300hpux.lo aout32.lo" ;;
724    i386aout_vec)		tb="$tb i386aout.lo aout32.lo" ;;
725    i386bsd_vec)		tb="$tb i386bsd.lo aout32.lo" ;;
726    i386coff_vec)		tb="$tb coff-i386.lo cofflink.lo" ;;
727    i386dynix_vec)		tb="$tb i386dynix.lo aout32.lo" ;;
728    i386freebsd_vec)		tb="$tb i386freebsd.lo aout32.lo" ;;
729    i386linux_vec)		tb="$tb i386linux.lo aout32.lo" ;;
730    i386lynx_aout_vec)		tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
731    i386lynx_coff_vec)		tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
732    i386mach3_vec)		tb="$tb i386mach3.lo aout32.lo" ;;
733    i386msdos_vec)		tb="$tb i386msdos.lo" ;;
734    i386netbsd_vec)		tb="$tb i386netbsd.lo aout32.lo" ;;
735    i386os9k_vec)		tb="$tb i386os9k.lo aout32.lo" ;;
736    i386pe_vec)			tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
737    i386pei_vec)		tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
738    i860coff_vec)		tb="$tb coff-i860.lo cofflink.lo" ;;
739    icoff_big_vec)		tb="$tb coff-i960.lo cofflink.lo" ;;
740    icoff_little_vec)		tb="$tb coff-i960.lo cofflink.lo" ;;
741    ieee_vec)			tb="$tb ieee.lo" ;;
742    m68k4knetbsd_vec)		tb="$tb m68k4knetbsd.lo aout32.lo" ;;
743    m68kaux_coff_vec)		tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
744    m68kcoff_vec)		tb="$tb coff-m68k.lo cofflink.lo" ;;
745    m68kcoffun_vec)		tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
746    m68klinux_vec)		tb="$tb m68klinux.lo aout32.lo" ;;
747    m68klynx_aout_vec)		tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
748    m68klynx_coff_vec)		tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
749    m68knetbsd_vec)		tb="$tb m68knetbsd.lo aout32.lo" ;;
750    m68ksysvcoff_vec)		tb="$tb coff-svm68k.lo cofflink.lo" ;;
751    m88kbcs_vec)		tb="$tb coff-m88k.lo" ;;
752    m88kmach3_vec)		tb="$tb m88kmach3.lo aout32.lo" ;;
753    m88kopenbsd_vec)		tb="$tb m88kopenbsd.lo aout32.lo" ;;
754    maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
755    mach_o_be_vec)              tb="$tb mach-o.lo" ;;
756    mach_o_le_vec)              tb="$tb mach-o.lo" ;;
757    mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
758    mcore_pe_big_vec)		tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
759    mcore_pe_little_vec)	tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
760    mcore_pei_big_vec)		tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
761    mcore_pei_little_vec)	tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
762    mipslpe_vec)		tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
763    mipslpei_vec)		tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
764    newsos3_vec)		tb="$tb newsos3.lo aout32.lo" ;;
765    nlm32_alpha_vec)		tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
766    nlm32_i386_vec)		tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
767    nlm32_powerpc_vec)		tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
768    nlm32_sparc_vec)		tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
769    or32coff_big_vec)		tb="$tb coff-or32.lo cofflink.lo" ;;
770    pc532machaout_vec)		tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
771    pc532netbsd_vec)		tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
772    pef_vec)                    tb="$tb pef.lo" ;;
773    pef_xlib_vec)               tb="$tb pef.lo" ;;
774    pdp11_aout_vec)		tb="$tb pdp11.lo" ;;
775    pmac_xcoff_vec)		tb="$tb coff-rs6000.lo xcofflink.lo" ;;
776    ppcboot_vec)		tb="$tb ppcboot.lo" ;;
777    riscix_vec)			tb="$tb aout32.lo riscix.lo" ;;
778    rs6000coff64_vec)		tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
779    rs6000coff_vec)		tb="$tb coff-rs6000.lo xcofflink.lo" ;;
780    shcoff_small_vec)		tb="$tb coff-sh.lo cofflink.lo" ;;
781    shcoff_vec)			tb="$tb coff-sh.lo cofflink.lo" ;;
782    shlcoff_small_vec)		tb="$tb coff-sh.lo cofflink.lo" ;;
783    shlcoff_vec)		tb="$tb coff-sh.lo cofflink.lo" ;;
784    shlpe_vec)			tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
785    shlpei_vec)			tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
786    som_vec)			tb="$tb som.lo" ;;
787    sparccoff_vec)		tb="$tb coff-sparc.lo" ;;
788    sparcle_aout_vec)		tb="$tb aout-sparcle.lo aout32.lo" ;;
789    sparclinux_vec)		tb="$tb sparclinux.lo aout32.lo" ;;
790    sparclynx_aout_vec)		tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
791    sparclynx_coff_vec)		tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
792    sparcnetbsd_vec)		tb="$tb sparcnetbsd.lo aout32.lo" ;;
793    sunos_big_vec)		tb="$tb sunos.lo aout32.lo" ;;
794    sym_vec)                    tb="$tb xsym.lo" ;;
795    tic30_aout_vec)		tb="$tb aout-tic30.lo" ;;
796    tic30_coff_vec)		tb="$tb coff-tic30.lo" ;;
797    tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
798    tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
799    tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
800    tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
801    tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
802    tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
803    tic54x_coff0_beh_vec)	tb="$tb coff-tic54x.lo" ;;
804    tic54x_coff0_vec)		tb="$tb coff-tic54x.lo" ;;
805    tic54x_coff1_beh_vec)	tb="$tb coff-tic54x.lo" ;;
806    tic54x_coff1_vec)		tb="$tb coff-tic54x.lo" ;;
807    tic54x_coff2_beh_vec)	tb="$tb coff-tic54x.lo" ;;
808    tic54x_coff2_vec)		tb="$tb coff-tic54x.lo" ;;
809    tic80coff_vec)		tb="$tb coff-tic80.lo cofflink.lo" ;;
810    vaxnetbsd_vec)		tb="$tb vaxnetbsd.lo aout32.lo" ;;
811    vax1knetbsd_vec)		tb="$tb vax1knetbsd.lo aout32.lo" ;;
812    vaxbsd_vec)			tb="$tb vaxbsd.lo aout32.lo" ;;
813    versados_vec)		tb="$tb versados.lo" ;;
814    vms_alpha_vec)		tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
815    vms_vax_vec)		tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
816    w65_vec)			tb="$tb coff-w65.lo reloc16.lo" ;;
817    we32kcoff_vec)		tb="$tb coff-we32k.lo" ;;
818    z8kcoff_vec)		tb="$tb coff-z8k.lo reloc16.lo" ;;
819
820    # These appear out of order in targets.c
821    srec_vec)			tb="$tb srec.lo" ;;
822    symbolsrec_vec)		tb="$tb srec.lo" ;;
823    tekhex_vec)			tb="$tb tekhex.lo" ;;
824    cisco_core_big_vec)		tb="$tb cisco-core.lo" ;;
825    cisco_core_little_vec)	tb="$tb cisco-core.lo" ;;
826
827    "")			;;
828    *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
829    esac
830
831    if test ${target_size} = 64; then
832	target64=true
833    fi
834    if test x"${vec}" = x"${defvec}"; then
835	bfd_default_target_size=${target_size}
836    fi
837done
838
839# Target architecture .o files.
840# A couple of CPUs use shorter file names to avoid problems on DOS
841# filesystems.
842ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
843
844# Weed out duplicate .o files.
845f=""
846for i in $tb ; do
847    case " $f " in
848    *" $i "*) ;;
849    *) f="$f $i" ;;
850    esac
851done
852tb="$f"
853
854f=""
855for i in $ta ; do
856    case " $f " in
857    *" $i "*) ;;
858    *) f="$f $i" ;;
859    esac
860done
861ta="$f"
862
863bfd_backends="$tb"
864bfd_machines="$ta"
865
866if test x${all_targets} = xtrue ; then
867  bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
868  bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
869  selvecs=
870  havevecs=
871  selarchs=
872  test -n "$assocvecs" &&
873    assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
874else	# all_targets is true
875  # Only set these if they will be nonempty, for the clever echo.
876  havevecs=
877  assocvecs=
878  test -n "$selvecs" &&
879    havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
880  test -n "$selvecs" &&
881    selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
882  test -n "$selarchs" &&
883    selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
884fi	# all_targets is true
885
886case ${host64}-${target64}-${want64} in
887  *true*)
888    wordsize=64
889    bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
890    all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
891    if test $BFD_HOST_64_BIT_DEFINED = 0; then
892      AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
893      AC_MSG_WARN([your compiler may not have a 64 bit integral type])
894    fi
895    if test -n "$GCC" ; then
896       bad_64bit_gcc=no;
897       AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
898       # Add more tests for gcc versions with non-working 64-bit support here.
899       AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
900		    bad_64bit_gcc=yes;
901		    AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
902		    AC_MSG_RESULT(no))
903       if test $bad_64bit_gcc = yes ; then
904	 AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
905       fi
906    fi
907    ;;
908  false-false-false)
909    wordsize=32
910    bfd_libs='$(BFD32_LIBS)'
911    all_backends='$(BFD32_BACKENDS)'
912    ;;
913esac
914
915AC_SUBST(wordsize)
916AC_SUBST(bfd_libs)
917AC_SUBST(all_backends)
918AC_SUBST(bfd_backends)
919AC_SUBST(bfd_machines)
920AC_SUBST(bfd_default_target_size)
921
922# Determine the host dependant file_ptr a.k.a. off_t type.  In order
923# prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
924# fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
925# Hopefully a reasonable assumption since fseeko et.al. should be
926# upward compatible.
927AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
928if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
929    AC_CHECK_SIZEOF(off_t)
930fi
931AC_MSG_CHECKING([file_ptr type])
932bfd_file_ptr="long"
933bfd_ufile_ptr="unsigned long"
934if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
935	-o x"${ac_cv_sizeof_off_t}" = x8; then
936    bfd_file_ptr=BFD_HOST_64_BIT
937    bfd_ufile_ptr=BFD_HOST_U_64_BIT
938fi
939AC_MSG_RESULT($bfd_file_ptr)
940AC_SUBST(bfd_file_ptr)
941AC_SUBST(bfd_ufile_ptr)
942
943
944tdefaults=""
945test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
946test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
947test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
948test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
949test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
950AC_SUBST(tdefaults)
951
952dnl AC_CHECK_HEADERS(sys/mman.h)
953AC_FUNC_MMAP
954AC_CHECK_FUNCS(madvise mprotect)
955case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
956  true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
957esac
958
959rm -f doc/config.status
960AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h])
961AC_OUTPUT
962